mirror of
https://github.com/curl/curl.git
synced 2026-01-18 17:21:26 +01:00
8db0e286b3
- drop x-hacks for curl internal variables and certain autotools ones that do not hold custom values. - make x-hacks consistently use `"x$var" = "xval"` style. - add a few x-hacks for input/external variables that may hold custom values. - prefer `-z` and `-n` to test empty/non-empty. This also makes some x-hacks unnecessary. - optimized negated test `-z` and `-n` options. - prefer `&&` and `||` over `-a` and `-o`. For better POSIX compatibility: https://pubs.opengroup.org/onlinepubs/9699919799/utilities/test.html - quote variables passed to `test`, where missing. - quote string literals in comparisons. - fix some indentation, whitespace. Note that a few `case` statements also use the x-hack, which looks unnecessary. This patch does not change them. Verified by comparing feature detection results with a reference CI run from before this patch (PR #19922). Refs: https://www.shellcheck.net/wiki/SC2268 https://pubs.opengroup.org/onlinepubs/9699919799/utilities/test.html https://www.vidarholen.net/contents/blog/?p=1035 https://mywiki.wooledge.org/BashPitfalls#A.5B_.24foo_.3D_.22bar.22_.5D Closes #18189
70 lines
2.4 KiB
Plaintext
70 lines
2.4 KiB
Plaintext
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
#***************************************************************************
|
|
|
|
AC_DEFUN([CURL_WITH_AMISSL], [
|
|
AC_MSG_CHECKING([whether to enable Amiga native SSL/TLS (AmiSSL v5)])
|
|
if test "$HAVE_PROTO_BSDSOCKET_H" = "1"; then
|
|
if test "x$OPT_AMISSL" != "xno"; then
|
|
ssl_msg=
|
|
AC_COMPILE_IFELSE([
|
|
AC_LANG_PROGRAM([[
|
|
#include <libraries/amisslmaster.h>
|
|
#include <openssl/opensslv.h>
|
|
]],[[
|
|
#if defined(AMISSL_CURRENT_VERSION) && defined(AMISSL_V3xx) && \
|
|
(OPENSSL_VERSION_NUMBER >= 0x30000000L) && \
|
|
defined(PROTO_AMISSL_H)
|
|
return 0;
|
|
#else
|
|
#error not AmiSSL v5 / OpenSSL 3
|
|
#endif
|
|
]])
|
|
],[
|
|
AC_MSG_RESULT([yes])
|
|
ssl_msg="AmiSSL"
|
|
test "amissl" != "$DEFAULT_SSL_BACKEND" || VALID_DEFAULT_SSL_BACKEND=yes
|
|
AMISSL_ENABLED=1
|
|
OPENSSL_ENABLED=1
|
|
# Use AmiSSL's built-in ca bundle
|
|
check_for_ca_bundle=1
|
|
with_ca_fallback=yes
|
|
LIBS="-lamisslstubs -lamisslauto $LIBS"
|
|
CURL_NETWORK_AND_TIME_LIBS="-lamisslstubs -lamisslauto $CURL_NETWORK_AND_TIME_LIBS"
|
|
AC_DEFINE(USE_AMISSL, 1, [if AmiSSL is in use])
|
|
AC_DEFINE(USE_OPENSSL, 1, [if OpenSSL is in use])
|
|
AC_CHECK_HEADERS(openssl/x509.h openssl/rsa.h openssl/crypto.h \
|
|
openssl/pem.h openssl/ssl.h openssl/err.h)
|
|
],[
|
|
AC_MSG_RESULT([no])
|
|
])
|
|
test -z "$ssl_msg" || ssl_backends="${ssl_backends:+$ssl_backends, }$ssl_msg"
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
|
|
])
|