mirror of
https://github.com/curl/curl.git
synced 2026-01-18 17:21:26 +01:00
16f073ef49
Rework the way curl's custom Find modules advertise their properties.
Before this patch, Find modules returned detected dependency properties
(header dirs, libs, libdirs, C flags, etc.) via global variables. curl's
main `CMakeLists.txt` copied their values into global lists, which it
later applied to targets. This solution worked internally, but it was
unsuited for the public, distributed `CURLConfig.cmake` and publishing
curl's Find modules with it, due to polluting the namespace of consumer
projects. It's also impractical to apply the many individual variables
to every targets depending on libcurl.
To allow using Find modules in consumer projects, this patch makes them
define as imported interface targets, named `CURL::<dependency>`. Then
store dependency information as target properties. It avoids namespace
pollution and makes the dependency information apply automatically
to all targets using `CURL::libcurl_static`.
Find modules continue to return `*_FOUND` and `*_VERSION` variables.
For dependencies detected via `pkg-config`, CMake 3.16+ is recommended.
Older CMake versions have a varying degree of support for
propagating/handling library directories. This may cause issues in envs
where dependencies reside in non-system locations and detected via
`pkg-config` (e.g. macOS + Homebrew). Use `CURL_USE_PKGCONFIG=OFF`
to fix these issues. Or upgrade to newer CMake, or link libcurl
dynamically.
Also:
- re-enable `pkg-config` for old cmake `find_library()` integration
tests.
- make `curlinfo` build after these changes.
- distribute local Find modules.
- export the raw list of lib dependencies via `CURL_LIBRARIES_PRIVATE`.
- `CURLconfig.cmake`: use curl's Find modules to detect dependencies in
the consumer env.
- add custom property to target property debug function.
- the curl build process no longer modifies `CMAKE_C_FLAGS`.
Follow-up to e86542038d #17047
Ref: #14930
Ref: https://github.com/libssh2/libssh2/pull/1535
Ref: https://github.com/libssh2/libssh2/pull/1571
Ref: https://github.com/libssh2/libssh2/pull/1581
Ref: https://github.com/libssh2/libssh2/pull/1623
Closes #16973
85 lines
2.7 KiB
CMake
85 lines
2.7 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the quiche library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `QUICHE_INCLUDE_DIR`: Absolute path to quiche include directory.
|
|
# - `QUICHE_LIBRARY`: Absolute path to `quiche` library.
|
|
#
|
|
# Defines:
|
|
#
|
|
# - `QUICHE_FOUND`: System has quiche.
|
|
# - `QUICHE_VERSION`: Version of quiche.
|
|
# - `CURL::quiche`: quiche library target.
|
|
|
|
set(_quiche_pc_requires "quiche")
|
|
|
|
if(CURL_USE_PKGCONFIG AND
|
|
NOT DEFINED QUICHE_INCLUDE_DIR AND
|
|
NOT DEFINED QUICHE_LIBRARY)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(_quiche ${_quiche_pc_requires})
|
|
endif()
|
|
|
|
if(_quiche_FOUND)
|
|
set(Quiche_FOUND TRUE)
|
|
set(QUICHE_FOUND TRUE)
|
|
set(QUICHE_VERSION ${_quiche_VERSION})
|
|
message(STATUS "Found Quiche (via pkg-config): ${_quiche_INCLUDE_DIRS} (found version \"${QUICHE_VERSION}\")")
|
|
else()
|
|
find_path(QUICHE_INCLUDE_DIR NAMES "quiche.h")
|
|
find_library(QUICHE_LIBRARY NAMES "quiche")
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(Quiche
|
|
REQUIRED_VARS
|
|
QUICHE_INCLUDE_DIR
|
|
QUICHE_LIBRARY
|
|
)
|
|
|
|
if(QUICHE_FOUND)
|
|
set(_quiche_INCLUDE_DIRS ${QUICHE_INCLUDE_DIR})
|
|
set(_quiche_LIBRARIES ${QUICHE_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(QUICHE_INCLUDE_DIR QUICHE_LIBRARY)
|
|
endif()
|
|
|
|
if(QUICHE_FOUND)
|
|
if(CMAKE_VERSION VERSION_LESS 3.13)
|
|
link_directories(${_quiche_LIBRARY_DIRS})
|
|
endif()
|
|
|
|
if(NOT TARGET CURL::quiche)
|
|
add_library(CURL::quiche INTERFACE IMPORTED)
|
|
set_target_properties(CURL::quiche PROPERTIES
|
|
INTERFACE_LIBCURL_PC_MODULES "${_quiche_pc_requires}"
|
|
INTERFACE_COMPILE_OPTIONS "${_quiche_CFLAGS}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${_quiche_INCLUDE_DIRS}"
|
|
INTERFACE_LINK_DIRECTORIES "${_quiche_LIBRARY_DIRS}"
|
|
INTERFACE_LINK_LIBRARIES "${_quiche_LIBRARIES}")
|
|
endif()
|
|
endif()
|