mirror of
https://github.com/curl/curl.git
synced 2026-01-18 17:21:26 +01:00
16f073ef49
Rework the way curl's custom Find modules advertise their properties.
Before this patch, Find modules returned detected dependency properties
(header dirs, libs, libdirs, C flags, etc.) via global variables. curl's
main `CMakeLists.txt` copied their values into global lists, which it
later applied to targets. This solution worked internally, but it was
unsuited for the public, distributed `CURLConfig.cmake` and publishing
curl's Find modules with it, due to polluting the namespace of consumer
projects. It's also impractical to apply the many individual variables
to every targets depending on libcurl.
To allow using Find modules in consumer projects, this patch makes them
define as imported interface targets, named `CURL::<dependency>`. Then
store dependency information as target properties. It avoids namespace
pollution and makes the dependency information apply automatically
to all targets using `CURL::libcurl_static`.
Find modules continue to return `*_FOUND` and `*_VERSION` variables.
For dependencies detected via `pkg-config`, CMake 3.16+ is recommended.
Older CMake versions have a varying degree of support for
propagating/handling library directories. This may cause issues in envs
where dependencies reside in non-system locations and detected via
`pkg-config` (e.g. macOS + Homebrew). Use `CURL_USE_PKGCONFIG=OFF`
to fix these issues. Or upgrade to newer CMake, or link libcurl
dynamically.
Also:
- re-enable `pkg-config` for old cmake `find_library()` integration
tests.
- make `curlinfo` build after these changes.
- distribute local Find modules.
- export the raw list of lib dependencies via `CURL_LIBRARIES_PRIVATE`.
- `CURLconfig.cmake`: use curl's Find modules to detect dependencies in
the consumer env.
- add custom property to target property debug function.
- the curl build process no longer modifies `CMAKE_C_FLAGS`.
Follow-up to e86542038d #17047
Ref: #14930
Ref: https://github.com/libssh2/libssh2/pull/1535
Ref: https://github.com/libssh2/libssh2/pull/1571
Ref: https://github.com/libssh2/libssh2/pull/1581
Ref: https://github.com/libssh2/libssh2/pull/1623
Closes #16973
120 lines
4.6 KiB
CMake
120 lines
4.6 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the ldap library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `LDAP_INCLUDE_DIR`: Absolute path to ldap include directory.
|
|
# - `LDAP_LIBRARY`: Absolute path to `ldap` library.
|
|
# - `LDAP_LBER_LIBRARY`: Absolute path to `lber` library.
|
|
#
|
|
# Defines:
|
|
#
|
|
# - `LDAP_FOUND`: System has ldap.
|
|
# - `LDAP_VERSION`: Version of ldap.
|
|
# - `CURL::ldap`: ldap library target.
|
|
|
|
set(_ldap_pc_requires "ldap" "lber")
|
|
|
|
if(CURL_USE_PKGCONFIG AND
|
|
NOT DEFINED LDAP_INCLUDE_DIR AND
|
|
NOT DEFINED LDAP_LIBRARY AND
|
|
NOT DEFINED LDAP_LBER_LIBRARY)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(_ldap ${_ldap_pc_requires})
|
|
endif()
|
|
|
|
if(_ldap_FOUND)
|
|
set(LDAP_FOUND TRUE)
|
|
set(LDAP_VERSION ${_ldap_ldap_VERSION})
|
|
message(STATUS "Found LDAP (via pkg-config): ${_ldap_INCLUDE_DIRS} (found version \"${LDAP_VERSION}\")")
|
|
else()
|
|
set(_ldap_pc_requires "") # Depend on pkg-config only when found via pkg-config
|
|
|
|
# On Apple the SDK LDAP gets picked up from
|
|
# 'MacOSX.sdk/System/Library/Frameworks/LDAP.framework/Headers', which contains
|
|
# ldap.h and lber.h both being stubs to include <ldap.h> and <lber.h>.
|
|
# This causes an infinite inclusion loop in compile. Also do this for libraries
|
|
# to avoid picking up the 'ldap.framework' with a full path.
|
|
set(_save_cmake_system_framework_path ${CMAKE_SYSTEM_FRAMEWORK_PATH})
|
|
set(CMAKE_SYSTEM_FRAMEWORK_PATH "")
|
|
find_path(LDAP_INCLUDE_DIR NAMES "ldap.h")
|
|
find_library(LDAP_LIBRARY NAMES "ldap")
|
|
find_library(LDAP_LBER_LIBRARY NAMES "lber")
|
|
set(CMAKE_SYSTEM_FRAMEWORK_PATH ${_save_cmake_system_framework_path})
|
|
|
|
unset(LDAP_VERSION CACHE)
|
|
if(LDAP_INCLUDE_DIR AND EXISTS "${LDAP_INCLUDE_DIR}/ldap_features.h")
|
|
set(_version_regex1 "#[\t ]*define[\t ]+LDAP_VENDOR_VERSION_MAJOR[\t ]+([0-9]+).*")
|
|
set(_version_regex2 "#[\t ]*define[\t ]+LDAP_VENDOR_VERSION_MINOR[\t ]+([0-9]+).*")
|
|
set(_version_regex3 "#[\t ]*define[\t ]+LDAP_VENDOR_VERSION_PATCH[\t ]+([0-9]+).*")
|
|
file(STRINGS "${LDAP_INCLUDE_DIR}/ldap_features.h" _version_str1 REGEX "${_version_regex1}")
|
|
file(STRINGS "${LDAP_INCLUDE_DIR}/ldap_features.h" _version_str2 REGEX "${_version_regex2}")
|
|
file(STRINGS "${LDAP_INCLUDE_DIR}/ldap_features.h" _version_str3 REGEX "${_version_regex3}")
|
|
string(REGEX REPLACE "${_version_regex1}" "\\1" _version_str1 "${_version_str1}")
|
|
string(REGEX REPLACE "${_version_regex2}" "\\1" _version_str2 "${_version_str2}")
|
|
string(REGEX REPLACE "${_version_regex3}" "\\1" _version_str3 "${_version_str3}")
|
|
set(LDAP_VERSION "${_version_str1}.${_version_str2}.${_version_str3}")
|
|
unset(_version_regex1)
|
|
unset(_version_regex2)
|
|
unset(_version_regex3)
|
|
unset(_version_str1)
|
|
unset(_version_str2)
|
|
unset(_version_str3)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(LDAP
|
|
REQUIRED_VARS
|
|
LDAP_INCLUDE_DIR
|
|
LDAP_LIBRARY
|
|
LDAP_LBER_LIBRARY
|
|
VERSION_VAR
|
|
LDAP_VERSION
|
|
)
|
|
|
|
if(LDAP_FOUND)
|
|
set(_ldap_INCLUDE_DIRS ${LDAP_INCLUDE_DIR})
|
|
set(_ldap_LIBRARIES ${LDAP_LIBRARY} ${LDAP_LBER_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(LDAP_INCLUDE_DIR LDAP_LIBRARY LDAP_LBER_LIBRARY)
|
|
endif()
|
|
|
|
if(LDAP_FOUND)
|
|
if(CMAKE_VERSION VERSION_LESS 3.13)
|
|
link_directories(${_ldap_LIBRARY_DIRS})
|
|
endif()
|
|
|
|
if(NOT TARGET CURL::ldap)
|
|
add_library(CURL::ldap INTERFACE IMPORTED)
|
|
set_target_properties(CURL::ldap PROPERTIES
|
|
INTERFACE_LIBCURL_PC_MODULES "${_ldap_pc_requires}"
|
|
INTERFACE_COMPILE_OPTIONS "${_ldap_CFLAGS}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${_ldap_INCLUDE_DIRS}"
|
|
INTERFACE_LINK_DIRECTORIES "${_ldap_LIBRARY_DIRS}"
|
|
INTERFACE_LINK_LIBRARIES "${_ldap_LIBRARIES}")
|
|
endif()
|
|
endif()
|